在微機(jī)測(cè)控系統(tǒng)中，經(jīng)常要用到A/D轉(zhuǎn)換。常用的方法是擴(kuò)展一塊或多塊A/D采集卡。當(dāng)模擬量較少或是溫度、壓力等緩變信號(hào)場(chǎng)合，采用總線型A/D卡并不是最合適、最經(jīng)濟(jì)的方案。這里介紹一種以GNS97C2051單片機(jī)為核心，采用TLC2543 12位串行A/D轉(zhuǎn)換器構(gòu)成的采樣模塊，該模塊的采樣數(shù)據(jù)由單片機(jī)串口經(jīng)電平轉(zhuǎn)換后送到上位機(jī)（IBM PC兼容機(jī)）的串口COM1或COM2，形成一種串行數(shù)據(jù)采集串行數(shù)據(jù)傳輸?shù)姆绞?。?jīng)實(shí)踐調(diào)試證實(shí)：該模塊功耗低、采樣精度高、可靠性好、接口簡(jiǎn)便，有一定實(shí)用價(jià)值。
1 主要器件介紹

1.1 TLC2543串行A/D轉(zhuǎn)換器

    模塊采用TI公司的TLC2543 12位串行A/D轉(zhuǎn)換器，使用開關(guān)電容逐次逼近技術(shù)完成A/D轉(zhuǎn)換過程。由于是串行輸入結(jié)構(gòu)，能夠節(jié)省51系列單片機(jī)I/O資源，且價(jià)格適中。其特點(diǎn)有：

（1）12位分辨率A/D轉(zhuǎn)換器；

（2）在工作溫度范圍內(nèi)10μs轉(zhuǎn)換時(shí)間；

（3）11個(gè)模擬輸入通道；

（4）3路內(nèi)置自測(cè)試方式；

（5）采樣率為66kbps；

（6）線性誤差+1LSB（max）

（7）有轉(zhuǎn)換結(jié)束（EOC）輸出；

（8）具有單、雙極性輸出；

（9）可編程的MSB或LSB前導(dǎo)；

（10）可編程的輸出數(shù)據(jù)長(zhǎng)度。

    TLC2543的引腳排列如圖1所示。圖1中AIN0～AIN10為模擬輸入端；為片選端；DIN 為串行數(shù)據(jù)輸入端；DOUT為A/D轉(zhuǎn)換結(jié)果的三態(tài)串行輸出端；EOC為轉(zhuǎn)換結(jié)束端；CLK為I/O時(shí)鐘；REF+為正基準(zhǔn)電壓端；REF-為負(fù)基準(zhǔn)電壓端；VCC為電源；GND為地。

1.2 GMS97C2051單片機(jī)

    GMS97C2051是武漢力源公司和韓國(guó)LG公司聯(lián)合推出的一種性能價(jià)格比極高的 8位單片機(jī)，其指令系統(tǒng)與MCS-51系列完全兼容。GMS97C2051與AT89C2051兼容（可直接替換），但其性能價(jià)格比優(yōu)于AT89C2051。引腳排列如圖2所示。

1.3 電平轉(zhuǎn)換器MAX3232

    MAX3232為RS-232收發(fā)器，簡(jiǎn)單易用，單+5V電源供電，僅需外接幾個(gè)電容即可完成從TTL電平到RS-232電平的轉(zhuǎn)換，引腳排列如圖3所示。

2 硬件設(shè)計(jì)

硬件電路如圖4所示。
  

    單片機(jī)GMS97C2051是整個(gè)系統(tǒng)的核心，TLC2543對(duì)輸入的模擬信號(hào)進(jìn)行采集，轉(zhuǎn)換結(jié)果由單片機(jī)通過P3.5（9腳）接收，AD芯片的通道選擇和方式數(shù)據(jù)通過P3.4（8腳）輸入到其內(nèi)部的一個(gè)8位地址和控制寄存器，單片機(jī)采集的數(shù)據(jù)通過串口（3、2腳）經(jīng)MAX3232轉(zhuǎn)換成RS232電平向上位機(jī)傳輸。圖中串行LCD顯示電路僅用于調(diào)試，對(duì)采集/傳輸?shù)臄?shù)據(jù)進(jìn)行監(jiān)測(cè)。

3 單片機(jī)軟件設(shè)計(jì)

    單片機(jī)程序主要包括串行數(shù)據(jù)采集模塊“DATA_SAM”和串行數(shù)據(jù)傳輸模塊“RS232”，調(diào)試所用到的顯示子程序在此略去。

    TLC2543的通道選擇和方式數(shù)據(jù)為8位，其功能為：D7、D6、D5和D4用來(lái)選擇要求轉(zhuǎn)換的通道，D7D6D5D4=0000時(shí)選擇0通道，D7D6D5D4=0001時(shí)選擇1通道，依次類推；D3和D2用來(lái)選擇輸出數(shù)據(jù)長(zhǎng)度，本程序選擇輸出數(shù)據(jù)長(zhǎng)度為12位，即D3D2=00或D3D2=10；D1，D0選擇輸入數(shù)據(jù)的導(dǎo)前位，D1D0=00選擇高位導(dǎo)前。

    TLC2543在每次I/O周期讀取的數(shù)據(jù)都是上次轉(zhuǎn)換的結(jié)果，當(dāng)前的轉(zhuǎn)換結(jié)果在下一個(gè)I/O周期中被串行移出。第一次讀數(shù)由于內(nèi)部調(diào)整，讀取的轉(zhuǎn)換結(jié)果可能不準(zhǔn)確，應(yīng)丟棄。

數(shù)據(jù)采集程序如下：

DATA_SAM: 
 MOV     R0,#30H ；數(shù)據(jù)緩沖區(qū)首地址30H→R0
 
 MOV     R1,#00000000B ；0通道方式/通道數(shù)據(jù)
 ACALL  RD_AD ；第一次讀取的轉(zhuǎn)換結(jié)果可能不準(zhǔn)確,丟棄。
 MOV     R1,#00010000B ；1通道方式/通道數(shù)據(jù)
 ACALL  RD_AD ；送1通道方式/通道數(shù)據(jù)并讀第0通道轉(zhuǎn)換結(jié)果
 MOV     @R0,R2 ；轉(zhuǎn)換結(jié)果存放到數(shù)據(jù)緩沖區(qū),下同
 INC    R0 
 MOV     @R0,R3 
 INC    R0 
 MOV     R1,#00100000B ；2通道方式/通道數(shù)據(jù)
 ACALL  RD_AD ；送2通道方式/通道數(shù)據(jù)并讀第1通道轉(zhuǎn)換結(jié)果
 MOV     @R0,R2 
 INC    R0 
 MOV     @RO,R3 
 INC    R0 
 ………… ；其它通道操作方式類推
 RET 

    單片機(jī)通過編程產(chǎn)生串行時(shí)鐘，并按時(shí)序發(fā)送與接收數(shù)據(jù)位，完成通道方式/通道數(shù)據(jù)的寫入和轉(zhuǎn)換結(jié)果的讀出，程序如下，供數(shù)據(jù)采集模塊“DATA_SAM” 調(diào)用。

 CLK    EQU      P3.3 
 DIN    EQU      P3.4 
 DOUT   EQU      P3.5 
 CS      EQU     P3.7 
RD_AD: 
 CLR    CLK ；清I/O時(shí)鐘
 SETB   CS ；設(shè)置片選為高
 CLR    CS ；設(shè)置片選為低
 MOV     R4,#08 ；先讀高8位
 MOV    A, R1 ；把方式/通道控制字放到A
LOP1: 
     MOV    C,DOUT ；讀轉(zhuǎn)換結(jié)果
 RLC    A ；A寄存器左移，移入結(jié)果數(shù)據(jù)位，移出方式/通道控制位
 MOV     DIN,C ；輸出方式/通道位
 SETB   CLK ；設(shè)置I/O時(shí)鐘為高
 CLR    CLK ；清I/O時(shí)鐘
 DJNZ   R4,LOP1 ；R4不為0，則返回LOP1
 MOV     R2,A ；轉(zhuǎn)換結(jié)果的高8位放到R2中
 MOV     A,#00H ；復(fù)位A寄存器
 MOV     R4,#04 ；再讀低4位
LOP2: 
 MOV     C,DOUT ；讀轉(zhuǎn)換結(jié)果
 RLC    A ；A寄存器左移，移入結(jié)果數(shù)據(jù)位
 SETB   CLK ；設(shè)置I/O時(shí)鐘為高
 CLR    CLK ；清I/O時(shí)鐘
 DJNZ   R4,LOP2 ；R4不為0，則返回LOP2
 MOV     R3,A ；轉(zhuǎn)換結(jié)果的低4位放到R3中
 SETB   CS ；設(shè)置片選為高
 RET 

    串行數(shù)據(jù)傳輸模塊包括串行口初始化子程序和數(shù)據(jù)傳輸子程序，各子程序分別如下。其中數(shù)據(jù)傳輸采用查詢方式，也可以方便地改為中斷方式。

INIT_COM: 
 MOV   SCON,#50H ；串口方式1工作，8位數(shù)據(jù)位，1位停止位，無(wú)奇偶校驗(yàn)
 MOV   PCON,#80H ；SMOD=1，波特率增倍
 MOV   TMOD,#20H ；波特率設(shè)置，fOSC=12MHz，波特率=2* 2400，N=0F3H
 MOV   TH1,#0F3H 
 MOV   TL1,#0F3H 
 SETB  TR1 ；啟動(dòng)定時(shí)器T1
 RET 
RS232: 
 MOV   R0,#30H ；緩沖區(qū)首地址30H→R0
 MOV   R5,#22 ；發(fā)送數(shù)據(jù)長(zhǎng)度→R5，11* 2=22
LOOP: 
 MOV   A,@R0 ；取數(shù)據(jù)→A
 MOV   SBUF,A ；數(shù)據(jù)→SBUF
WAIT:  
 JBC   TI,CONT ；判斷發(fā)送中斷標(biāo)志，是1則轉(zhuǎn)到CONT，并清TI
 SJMP  WAIT 
CONT: 
 INC   R0 
 DJNZ  R5,LOOP 
 RET 

4 上位機(jī)串口接收程序設(shè)計(jì)

    上位機(jī)接收數(shù)據(jù)所用C語(yǔ)言程序包括初始化子程序和接收子程序。各子程序分別如下：

void init_com1(void) /*初始化子程序*/
{
outportb(0x3fb,0x80); /*線控制寄存器高位置1，使波特率設(shè)置有效*/
outportb(0x3f8,0x18); /*波特率設(shè)置，與單片機(jī)波特率一致為4800bps*/
outportb(0x3f9,0x00);
outportb(0x3fb,0x03); /*線控制寄存器設(shè)置，8位數(shù)據(jù)位，1位停止位,無(wú)奇偶校驗(yàn)*/
outportb(0x3fc,0x03); /*Modem控制寄存器設(shè)置,使DTR和RTS輸出有效*/
outportb(0x3f9,0x00); /*設(shè)置中斷允許寄存器，禁止一切中斷*/
}
void receive_data(void) /*查詢方式接收數(shù)據(jù)子程序*/
{
     while(!kbhit())
     {
 while(!(inportb(0x3fd)&0x01));/*若接收寄存器為空，則等待*/
 printf("%x ",inportb(0x3f8)); /*讀取結(jié)果并顯示*/
     }
     getch();
}   

5 結(jié)論

    本文給出的硬件和軟件均經(jīng)過實(shí)踐檢驗(yàn)，并且已經(jīng)按照PC/104總線制作成數(shù)據(jù)采集卡，使用很方便，能夠滿足對(duì)數(shù)據(jù)采樣頻率要求不是特別高的應(yīng)用場(chǎng)合。